Class XbpBrowse() Foundation

// In the example, the user defined function GuiBrowseDB() is 
// programmed. It assigns all navigation code blocks to an 
// XbpBrowse object which are necessary to browse a database. 
// Table columns are created within a FOR..NEXT loop. 
// The browser is displayed in the event loop. 

#include "Appevent.ch" 
#include "Common.ch" 

PROCEDURE AppSys 
// Desktop remains application window 
RETURN 


PROCEDURE Main 
   LOCAL nEvent, mp1, mp2, oXbp, oBrowse, cField, i 

   USE Customer NEW 

   // Create a hidden dialog window 
   oXbp := GuiStdDialog( "Standard GUI Browser for DBF" ) 

   // Create browser in the window 
   oBrowse := GuiBrowseDb( oXbp:drawingArea ) 

   // Add columns for all fields of the database 
   FOR i:=1 TO FCount() 
      cField := FieldName( i ) 
      oBrowse:addColumn( FieldBlock(cField), , cField ) 
   NEXT 

   // The browser always fills the entire window after :resize() 
   oXbp:drawingArea:resize := ; 
      {|mp1,mp2,obj| obj:childList()[1]:setSize(mp2) } 

   oXbp:show() 
   oBrowse:show() 
   SetAppFocus( oBrowse ) 

   DO WHILE nEvent <> xbeP_Close 
      nEvent := AppEvent( @mp1, @mp2, @oXbp ) 
      oXbp:handleEvent( nEvent, mp1, mp2 ) 
   ENDDO 
RETURN 


****************************************************************** 
* Create a GUI browser with navigation code blocks for a database 
****************************************************************** 
FUNCTION GuiBrowseDB( oParent, aPos, aSize ) 
   LOCAL oBrowse 

   oBrowse := XbpBrowse():new( oParent,, aPos, aSize ):create() 

   // Navigation code blocks for the browser   
   oBrowse:skipBlock     := {|n| DbSkipper(n) } 
   oBrowse:goTopBlock    := {| | DbGoTop()    } 
   oBrowse:goBottomBlock := {| | DbGoBottom() } 
   oBrowse:phyPosBlock   := {| | Recno()      } 
   oBrowse:goPhyPosBlock := {|n| DbGoto(n)    } 

   // Navigation code blocks for the vertical scroll bar 
   oBrowse:posBlock      := {| | DbPosition()    } 
   oBrowse:goPosBlock    := {|n| DbGoPosition(n) } 
   oBrowse:lastPosBlock  := {| | 100             } 
   oBrowse:firstPosBlock := {| | 0               } 

RETURN oBrowse 


****************************************************************** 
* Create a hidden dialog window 
****************************************************************** 
FUNCTION GuiStdDialog( cTitle ) 
   LOCAL oDlg 

   DEFAULT cTitle TO "Standard Dialog Window" 

   oDlg          := XbpDialog():new( ,,{10,10}, {600,400},, .F. ) 
   oDlg:icon     := 1 
   oDlg:taskList := .T. 
   oDlg:title    := cTitle 
   oDlg:create() 
   oDlg:drawingArea:setFontCompoundName( "8.Helv" ) 

RETURN oDlg 

// This example illustrates how XbpBrowse objects can be used for 
// browsing an array. In addition, the example shows how the 
// visualization of the browse can be adjusted for platforms which 
// support visual styles. This is important for computers running 
// Windows XP or newer. 

  ****************************************************************** 
  * IMPORTANT: A manifest file or resource must be added to the 
  * example! More information on defining manifests can be found 
  * in the documentation of the function "IsThemeActive()". 
  ****************************************************************** 

  #include "xbp.ch" 
  #include "appevent.ch" 

  #PRAGMA LIBRARY( "XPPUI2.LIB" ) 

  // Global variables for maintaining 
  // the data source (array) 
  STATIC aData 
  STATIC nLastRec 
  STATIC nRecno   

  PROCEDURE Main() 

   LOCAL oBrowse 
   LOCAL nEvent 
   LOCAL oXbp := NIL 
   LOCAL mp1  := NIL 
   LOCAL mp2  := NIL 
   LOCAL oCol 
   LOCAL nWidth 
   LOCAL oGroup 

     // Configure the application window (XbpCrt) 
     SetMouse( .T. ) 
     SetColor( "N/W+" ) 
     CLS 
     SetAppWindow():UseShortCuts := .T. 

     // Create group box as backdrop for the 
     // browse 
     oGroup := XbpStatic():New() 
     oGroup:Type    := XBPSTATIC_TYPE_GROUPBOX 
     oGroup:Caption := "Inventory" 
     oGroup:Create( ,,, {440,250} ) 

     CenterControl( oGroup ) 

     // Initialize array data for the browse as 
     // well as associated status variables 
     aData    := { {"Magazines",  133, .T.},; 
                   {"Newspapers", 15,  .T.},; 
                   {"Books",      32,  .T.},; 
                   {"Postcards",  833, .F.} } 
     nLastRec := Len(aData) 
     nRecno   := 1 

     // Create the browse and associate it with the 
     // data source. Note that visual styles are 
     // switched off to ensure that cell frames are 
     // displayed as configured, irrespective of the 
     // operating system being used 
     oBrowse := XbpBrowse():New( oGroup ) 
     oBrowse:SkipBlock     := {|nSkip,oBrowse| DoSkip(nSkip,oBrowse) } 
     oBrowse:GoBottomBlock := {||  nRecno := Len(aData) } 
     oBrowse:GoTopBlock    := {||  nRecno := 1 } 
     oBrowse:PosBlock      := {||  nRecno } 
     oBrowse:PhyPosBlock   := {||  nRecno } 
     oBrowse:GoPhyPosBlock := {|n| nRecno := n } 

     oBrowse:LastPosBlock  := {|| Len(aData) } 
     oBrowse:FirstPosBlock := {|| 1 } 
     oBrowse:CursorMode    := XBPBRW_CURSOR_ROW 
     oBrowse:UseVisualStyle := .F. 
     oBrowse:Create( ,, {20,20}, {400,200},, .F. ) 

     // Add columns to the browse 
     oBrowse:AddColumn( {|| aData[nRecno,1]}, 15, "Publication" ) 
     oBrowse:AddColumn( {|| aData[nRecno,2]}, 5,  "In Stock" ) 
     oBrowse:AddColumn( {|| aData[nRecno,3]}, 1,  "Web Shop" ) 

     // Enable visual styles for the scroll 
     // bars. This way, the data area remains 
     // fully configurable while the scroll 
     // bars use platform-default visuals. 
     oBrowse:HScrollObject:UseVisualStyle  := .T. 
     oBrowse:VScrollObject:UseVisualStyle  := .T. 

     oBrowse:Show() 
     SetAppFocus( oBrowse ) 

     nEvent := xbeP_None 
     DO WHILE nEvent != xbeP_Close 
        nEvent := AppEvent( @mp1, @mp2, @oXbp ) 
        oXbp:HandleEvent( nEvent, mp1, mp2 ) 
     ENDDO 

     oBrowse:Destroy() 

  RETURN 

  ****************************************************************** 
  * Skipper function that moves the record pointer through the 
  * data source (array) 
  ****************************************************************** 
  FUNCTION DoSkip( nSkip ) 

   LOCAL nCanSkip 

     IF nRecno + nSkip < 1             // "BoF" 
        nCanSkip := 1 - nRecno 
     ELSEIF nRecno + nSkip > nLastRec  // "EoF" 
        nCanSkip := nLastRec - nRecno 
     ELSE 
        nCanSkip := nSkip 
     ENDIF 

     nRecno += nCanSkip 

  RETURN nCanSkip