Operator Operator < | Xbase++

Less than operator (binary): size comparison of two values.

<Expression1> < <Expression2>

<Expression1> and <Expression2> are expressions of the same data type, whose values are to be compared with each other.

The less than operator compares two values of the same data type and returns the result of the comparison as a logical value. The result is .T. (true) only when <Expression1> is smaller than <Expression2>. Otherwise it is .F. (false).

Values of data type array, code block, object or Nil cannot be compared using this operator. A value with data type memo is handled like a value with data type character.

Comparison of characters

The settings of SET EXACT ON | OFF and SET LEXICAL ON | OFF are taken into account when comparing characters or character strings (see example). When SET LEXICAL is set to OFF, characters are compared with each other based on the collation table specified via the SET COLLATION command.

With SET EXACT OFF, the characters are compared up to the length of the right character string <Expression2>. With SET EXACT ON, the characters are compared up to the length of the left character string <Expression1> and trailing blanks are not considered.

The setting SET LEXICAL ON has precedence over SET EXACT ON. With SET LEXICAL ON, character comparisons are based on the country specific lexical character values defined by the operating system. The lexical value of one or more characters can be redefined with the function SetLexrule().

Comparison of date values

Values with data type date are compared with each other on a chronological basis.

Comparison of logical values

The value .F. (false) is smaller than the value .T. (true).

Comparison of numeric values

The comparison is based on the sizes of the numeric values.

The less than operator (The less than operator (<)

// This example illustrates the results of the less than operator 
// in various comparison expressions. The character string comparisons 
// show the various possibilities of using SET EXACT and SET LEXICAL. 

PROCEDURE Main 
   SET EXACT OFF 
                                    // character value 
   ? "A"  < "Z"                     // result: .T. 
   ? "A"  < "A "                    // result: .T. 
   ? "A " < "A"                     // result: .F. 
   ? ""   < "A"                     // result: .T. 
   ? "A"  < ""                      // result: .F. 
   ? "AB" < "ABC"                   // result: .T. 
   ? "ABC"< "AB"                    // result: .F. 

   SET EXACT ON 

   ? "A"  < "Z"                     // result: .T. 
   ? "A"  < "A "                    // result: .F. 
   ? "A " < "A"                     // result: .F. 
   ? ""   < "A"                     // result: .T. 
   ? "A"  < ""                      // result: .F. 
   ? "AB" < "ABC"                   // result: .T. 
   ? "ABC"< "AB"                    // result: .F. 

   SetLexrule( "ß", "ss" )          // "ß" translate to "ss" 
   ? "gross" < "groß"               // result: .T. 

   SET LEXICAL ON 
   ? "gross" < "groß"               // result: .F. 

   ? CtoD("12/31/94") < ;           // date value 
     CtoD("01/01/95")               // result: .T. 

                                    // logical value 
   ? .F. < .T.                      // result: .T. 

                                    // numeric value 
   ? 5 < 10                         // result: .T. 
   ? 10 < 5                         // result: .F. 

RETURN

If you see anything in the documentation that is not correct, does not match your experience with the particular feature or requires further clarification, please use this form to report a documentation issue.

Operator Operator < Foundation