Operator >= | Xbase++ | Alaska Software

Greater than or equal to operator (binary): size comparison of two values.

<Expression1> >= <Expression2>

<Expression1> and <Expression2> are expressions of the same data type whose values are to be compared with each other.

The greater than or equal to operator compares values of the same data type and returns the result of the comparison as a logical value. the results is .T. (true) only when the value of <Expression1> is greater than or equal to the value of <Expression2>. Otherwise it is .F. (false).

Values of the data type array, code block, object or NIL cannot be compared using this operator. A value with data type memo is handled like a value with data type character.

Comparison of characters

The settings of SET EXACT ON | OFF and SET LEXICAL ON | OFF are taken into account in comparing characters or character strings (see example). When SET LEXICAL is set to OFF, characters are compared with each other based on the collation table specified via the SET COLLATION command.

With SET EXACT OFF, the characters are compared up to the length of the right character string <Expression2>. With SET EXACT ON, the characters are compared up to the length of the left character string <Expression1> and trailing blanks are not considered.

The setting SET LEXICAL ON has precedence over SET EXACT ON. With SET LEXICAL ON, character comparisons are based on the country specific lexical character values defined by the operating system. The lexical value of one or more characters can be redefined with the function SetLexrule().

Comparison of date values

Values with data type date are compared on a chronological basis.

Comparison of logical values

The value .T. (true) is greater than the value .F. (false).

Comparison of numeric values

A comparison is based on the sizes of the numeric values.

The greater than or equal to operator (>=)

// This example illustrates the results of the greater than or 
// equal to operator with various comparison expressions. 
// The examples containing strings show the effects of 
// SET EXACT and SET LEXICAL on the comparison. 

PROCEDURE Main 
   SET EXACT OFF 
                                    // character value 
   ? "A"  >= "Z"                    // result: .F. 
   ? "A"  >= "A "                   // result: .F. 
   ? "A " >= "A"                    // result: .T. 
   ? ""   >= "A"                    // result: .F. 
   ? "A"  >= ""                     // result: .T. 
   ? "AB" >= "ABC"                  // result: .F. 
   ? "ABC">= "AB"                   // result: .T. 

   SET EXACT ON 

   ? "A"  >= "Z"                    // result: .F. 
   ? "A"  >= "A "                   // result: .T. 
   ? "A " >= "A"                    // result: .T. 
   ? ""   >= "A"                    // result: .F. 
   ? "A"  >= ""                     // result: .T. 
   ? "AB" >= "ABC"                  // result: .F. 
   ? "ABC">= "AB"                   // result: .T. 

   SetLexrule( "ß", "ss" )          // "ß" translates to "ss" 
   ? "gross" >= "groß"              // result: .F. 

   SET LEXICAL ON 
   ? "gross" >= "groß"              // result: .T. 

   ? CtoD("12/31/94") >= ;          // date value 
     CtoD("01/01/95")               // result: .F. 

                                    // logical value 
   ? .F. >= .T.                     // result: .F. 

                                    // numeric value 
   ? 5 >= 10                        // result: .F. 
   ? 10 >= 5                        // result: .T. 

RETURN

If you see anything in the documentation that is not correct, does not match your experience with the particular feature or requires further clarification, please use this form to report a documentation issue.

Operator >= Foundation