<Expression>
<Expression1> and <Expression2> are expressions of the same data type or the value NIL. The values of the two expressions are tested for equality. Each data type can be tested for equal NIL.
Operator = (comparison) Foundation
Simple equality operator (binary): testing two values for equality.
Syntax
<Expression1> = <Expression2>Parameters
Description
The simple equality operator compares two values of the same data type and returns the result of the comparison as a logical value. The result is .T. (true) only when the value of <Expression1> equals the value of <Expression2>. Otherwise it is .F. (false).
Comparison with NIL
The equals operator can compare values of all data types (including array, code block and object) with the value NIL. In this case, the value .T. (true) is returned only when both expressions are equal to NIL.
Comparison of characters
The settings of SET EXACT ON | OFF and SET LEXICAL ON | OFF are taken into account in comparing characters or character strings (see example). When SET LEXICAL is set to OFF, characters are compared with each other based on the collation table specified via the SET COLLATION command.
With SET EXACT OFF, the characters are compared up to the length of the right character string <Expression2>. With SET EXACT ON, the characters are compared up to the length of the left character string <Expression1> and trailing blanks are not considered. If <Expression2> contains a null string (""), the simple equal operator always returns the value .T. (true) with SET EXACT OFF, and always returns the value .F. (false) with SET EXACT ON unless both operands contain a null string.
The setting SET LEXICAL ON has precedence over SET EXACT ON. When SET LEXICAL ON, character comparisons are based on the country specific lexical character values defined by the operating system. The lexical value of one or more characters can be redefined with the function SetLexrule().
Comparison of date values
Values with data type date are compared on a chronological basis.
Comparison of logical values
The value .F. (false) is not equal to the value .T. (true).
Comparison of numeric values
The comparison is based on the sizes of the numeric values.
Examples
// This example illustrates the results of the simple
// equality operator with various comparison expressions.
// The character string comparisons show the various possibilities of
// using SET EXACT and SET LEXICAL.
PROCEDURE Main
SET EXACT OFF
// character value
? "A" = "Z" // result: .F.
? "A" = "A " // result: .F.
? "A " = "A" // result: .T.
? "" = "A" // result: .F.
? "A" = "" // result: .T.
? "AB" = "ABC" // result: .F.
? "ABC"= "AB" // result: .T.
SET EXACT ON
? "A" = "Z" // result: .F.
? "A" = "A " // result: .T.
? "A " = "A" // result: .T.
? "" = "A" // result: .F.
? "A" = "" // result: .F.
? "AB" = "ABC" // result: .F.
? "ABC"= "AB" // result: .F.
SetLexrule( "ß", "ss" ) // "ß" translates to "ss"
? "gross" = "groß" // result: .F.
SET LEXICAL ON
? "gross" = "groß" // result: .T.
? CtoD("12/31/94") = ; // date value
CtoD("01/01/95") // result: .F.
// logical value
? .F. = .T. // result: .F.
// numeric value
? 5 = 10 // result: .F.
? 10 = 5 // result: .F.
// array
? {1,2,3} = NIL // result: .F.
RETURN
Feedback
If you see anything in the documentation that is not correct, does not match your experience with the particular feature or requires further clarification, please use this form to report a documentation issue.