Function PostAppEvent() Foundation

// The example demonstrates using PostAppEvent() for user-defined 
// events. The event codes are defined as #define constants with 
// 'xbeP_User' as the base value. In the example, the position 
// for a box can be determined by mouse clicks and it is then 
// displayed. PostAppEvent() places the function values Date() 
// and Time() as message parameters into the event queue. The 
// example uses no addressee for the message, but illustrates 
// the general mechanism for transmitting a message using the 
// event queue. 

#include "Appevent.ch" 

#define  xbeU_DrawBox  xbeP_User + 1 
#define  xbeU_Quit     xbeP_User + 2 

PROCEDURE Main 
   LOCAL nEvent := 0, mp1, mp2 

   CLEAR 
   @ 0,0 SAY " Output box  |  QUIT" 
   SetMouse(.T.)                            // activate mouse 

   // infinite loop 
   DO WHILE .T. 
      nEvent := AppEvent( @mp1, @mp2,, 0 ) 

      DO CASE 
      CASE nEvent == xbeU_DrawBox           // mp1=Date(), mp2=Time() 
         DrawBox( mp1, mp2 )                // from PostAppEvent() 

      CASE nEvent == xbeU_Quit 
         QUIT 

      CASE nEvent < xbeB_Event 
         @ MaxRow(), 0 
         ?? "Key code is", nEvent 

      CASE nEvent == xbeM_LbClick          // click of left mouse 
                                           // button 

         IF mp1[1] == 0 .AND. mp1[2] <= 21 // click in first row 
            IF mp1[2] <= 15 
               PostAppEvent( xbeU_DrawBox, Date(), Time() ) 
            ELSE 
               PostAppEvent( xbeU_Quit ) 
            ENDIF 
         ELSE 
            @ mp1[1], mp1[2] SAY "No choice made" 
         ENDIF 
      ENDCASE 

   ENDDO 
RETURN 

********************************* 
PROCEDURE DrawBox( dDate, cTime ) 
   LOCAL nEvent := 0, mp1, mp2 
   LOCAL nTop, nLeft, nBottom, nRight 

   SAVE SCREEN 
   @ 0, 0 SAY "Click upper left corner of the box" 

   DO WHILE nEvent <> xbeM_LbClick          // establish coordinates 
      nEvent := AppEvent( @mp1, @mp2,, 0 ) 
   ENDDO 
   nTop   := mp1[1] 
   nLeft  := mp1[2] 
   nEvent := 0 

   @ nTop, nLeft SAY "Click lower right corner of the box" 

   DO WHILE nEvent <> xbeM_LbClick 
      nEvent  := AppEvent( @mp1, @mp2,, 0 ) 

      IF nEvent == xbeM_LbClick .AND.;      // incorrect coordinates 
         ( mp1[1] <= nTop .OR. mp1[2] <= nLeft ) 
         Tone(1000,1) 
         nEvent := 0 
      ENDIF 
   ENDDO 

   nBottom := mp1[1] 
   nRight  := mp1[2] 

   RESTORE SCREEN 
   @ nTop, nLeft TO nBottom, nRight 
   @ nTop+1,nLeft+1 SAY "Date:" 
   ?? dDate 

   @ nTop+2,nLeft+1 SAY " Time:" 
   ?? cTime 
RETURN 

// In the example, 26 pushbuttons and a multiple line entry field 
// are created. Each pushbutton displays a letter of the 
// alphabet. When a pushbutton is pressed, it sends a message 
// with the ASCII code of a letter to the input field. 
// The input field processes the applicable event and 
// displays the letter of the pushbutton in the edit buffer. 

#include "Appevent.ch" 

PROCEDURE Main 
   LOCAL nEvent, mp1, mp2, oXbp, oBtn, oMLE, bActivate, i 

   SetMouse( .T. )                  // process mouse events 
   SetColor( "N/W" )                // fill window 
   CLS                              // pale gray 

                                    // multiple line entry field 
   oMLE := XbpMLE():new(,, {20,50}, {600,240} ) 
   oMLE:create() 
   oMLE:setData( "Xbase++ - multiple line entry field" ) 

   // Activate code block for the pushbuttons: 
   // In the code block a message is posted to the MLE. 
   // oBtn is the pushbutton which was pressed. 
   // 
   bActivate := ; 
      {|mp1,mp2,oBtn| PostAppEvent( xbeP_Keyboard, ; 
                      Asc( oBtn:caption ),, oMLE ) } 

   FOR i:=1 TO 26                   // create 26 pushbuttons 
      oBtn := XbpPushButton():new(,, {23*i, 350}, {20, 32} ) 
      oBtn:caption  := Chr(64+i)    // each pushbutton places 
      oBtn:activate := bActivate    // a letter in the 
      oBtn:pointerFocus := .F.      // event queue 
      oBtn:create() 
   NEXT 

   nEvent := 0                      // process events 
   DO WHILE nEvent <> xbeP_Close 
      nEvent := AppEvent( @mp1, @mp2, @oXbp, 0 ) 
      IF nEvent == xbeK_ESC 
         EXIT 
      ELSEIF oXbp <> NIL 
         oXbp:handleEvent( nEvent, mp1, mp2, oXbp ) 
      ENDIF 
   ENDDO 

RETURN