Commands and Statements Commands and Statements

Command SET MESSAGE Foundation

Specifies the screen row for @...PROMPT messages.

Syntax
SET MESSAGE TO [<nRow> [CENTER | CENTRE]]
Scope
process-wide
Parameters
<nRow>
<nRow> is a numeric value specifying the row position where the messages specified in the MESSAGE option of the @...PROMPT command are output. When the value 0 is specified for <nRow> or when the argument is missing, the display of messages is suppressed.
CENTER
The option CENTER (or CENTRE) displays the messages centered on the specified screen row.
Description

The command SET MESSAGE sets the screen row where messages specified in the MESSAGE option of the command @...PROMPT are displayed. The initial value is 0, resulting in no messages being displayed by default. If a value > 0 is specified for <nRow>, output of the messages occurs left justified on this screen row. Centered output occurs when the option CENTER ( or CENTRE) is specified.

Examples
SET MESSAGE 
// In the example, a horizontal menu is programmed which 
// displays three menu items on the uppermost screen row and 
// the corresponding messages centered on the bottom row. 

PROCEDURE Main 
   LOCAL nMenuItem := 1 

   CLS 
   SetColor( "N/BG,W+/B" ) 
   @ 0, 0                  // fill first row with blank spaces 

   SET WRAP ON 
   SET MESSAGE TO MaxRow() CENTER 

   @ 0, 1 PROMPT " DBF file " ; 
         MESSAGE "Open and close DBF files" 

   @ Row(), Col()  PROMPT " NTX file " ; 
                  MESSAGE "Open and close index files" 

   @ Row(), Col()  PROMPT " Search " ; 
                  MESSAGE "Search records" 

   MENU TO nMenuItem 

   DO CASE 
   CASE nMenuItem == 0 
      ? "Terminated without selection" 
   CASE nMenuItem == 1 
      ? "Select DBF file" 
   CASE nMenuItem == 2 
      ? "Select index file" 
   CASE nMenuItem == 3 
      ? "Search record" 
   ENDCASE 

RETURN
Feedback

If you see anything in the documentation that is not correct, does not match your experience with the particular feature or requires further clarification, please use this form to report a documentation issue.