Commands and Statements

Command SET DELIMITERS Foundation

Sets the delimiting characters for GET entry fields and/or whether they are displayed.

Syntax 
SET DELIMITERS on | OFF | <lToggle>
SET DELIMITERS TO [<cDelimiter> | DEFAULT]
Scope
process-wide
Parameters
<lToggle>
<lToggle> is a logical expression which must appear in parentheses. Instead of the logical expression, the option ON can be specified for the value .T. (true) or OFF for the value .F. (false). When .T. or ON is specified, delimiting characters are displayed before and after GET entry fields.
<cDelimiter>
<cDelimiter> is a character expression defining one or two delimiting characters. If only one character is specified, this character is displayed at both sides of each GET entry field. If two characters are specified, the first character is displayed at the beginning (left) and the second at the end (right) of each entry field. The option DEFAULT specifies the colon as the default delimiter.
Description

The command SET DELIMITERS can turn on or off the automatic display of delimiting characters for GET entry fields, or it can define what the delimiting characters will be if the argument <cDelimiter> is specified. The display of delimiting characters is turned on with SET DELIMITERS ON, which extends the display of GET entry fields by two characters. This command is included for compatibility reasons. Delimiters are not generally needed, since GET entry fields can be color highlighted.

Examples
SET DELIMITERS 
// In the example, various delimiters are defined for 
// GET entry fields. 

PROCEDURE Main 
   LOCAL cString := "Xbase++" 
   LOCAL dDate   := Date() 
   LOCAL lBoolean:= .F. 
   LOCAL nNumber := 11123.45 
   LOCAL cText   := "A very long character string" 

   SET DELIMITERS ON 

   SET DELIMITERS TO ": " 
   @ 2, 2 SAY "Character value" GET cString 
   READ 

   SET DELIMITERS TO "<>" 
   @ 3, 2 SAY "Date value " GET dDate 
   READ 

   SET DELIMITERS TO "[]" 
   @ 4, 2 SAY "Boolean    " GET lBoolean PICTURE "Y" 
   READ 

   SET DELIMITERS TO "()" 
   @ 5, 2 SAY "Numeric value " GET nNumber 
   READ 

   SET DELIMITERS TO "||" 
   @ 6, 2 SAY "Scroll     " GET cText PICTURE "@S10" 
   READ 

RETURN
Feedback

If you see anything in the documentation that is not correct, does not match your experience with the particular feature or requires further clarification, please use this form to report a documentation issue.