Class XbpListBox() Foundation

// This example shows the basic process for creating a 
// listbox. The DbStruct() array of the database provides 
// the data source for the listbox and allows the selection 
// of one or more field names. Copying the field names from 
// the structure array into the listbox occurs in the UDF 
// ArrayToListBox(). The selected field names are copied from 
// the listbox into an array in the UDF ArrayFromListBox(). 

#include "Appevent.ch" 
#include "Xbp.ch" 

PROCEDURE Main 
   LOCAL nEvent, mp1, mp2, oXbp 
   LOCAL oListBox, aStruct 

   SetColor("N/W") 
   CLS 

   USE Customer NEW 
   aStruct := DbStruct() 
   CLOSE Customer 

   // Create list box that allows multiple selections 
   oListBox := XbpListbox():new() 
   oListBox:markMode := XBPLISTBOX_MM_MULTIPLE 
   oListBox:create( ,, {300, 100}, {200, 150} ) 

   // Copy field names from the DbStruct() array to the list box 
   ArrayToListBox( oListBox, aStruct ) 

   // Code block for list box selection: 
   //   The selected fields from the DbStruct() 
   //   array are displayed using QOut() 
   oListBox:ItemSelected := {|mp1, mp2, obj| ; 
       QOut( "Fields:", ArrayFromListBox( obj ) ) } 

   // Event loop 
   nEvent := 0 
   DO WHILE nEvent <> xbeP_Close 
      nEvent := AppEvent( @mp1, @mp2, @oXbp) 
      oXbp:HandleEvent( nEvent, mp1, mp2 ) 
   ENDDO 
RETURN 

************************************************************ 
* Copy array to list box 
************************************************************ 
FUNCTION ArrayToListBox( oListBox, aArray ) 
   LOCAL i := 0, imax := Len(aArray) 

   IF Valtype( aArray[1] ) == "A"    // 2-dim array 
      DO WHILE ++i <= imax           // copy first column 
         oListBox:addItem( aArray[i,1] ) 
      ENDDO 
   ELSE                              // 1-dim array 
      DO WHILE ++i <= imax           // copy array elements 
         oListBox:addItem( aArray[i] ) 
      ENDDO 
   ENDIF 
RETURN oListBox 

*************************************************************** 
* Copy marked items from list box to an array 
*************************************************************** 
STATIC FUNCTION ArrayFromListBox( oListBox ) 
   LOCAL aArray := oListBox:getData() // numeric indexes 
   LOCAL i := 0, imax := Len(aArray) 

   DO WHILE ++i <= imax               // assign character strings 
      aArray[i] := oListBox:getItem( aArray[i] ) 
   ENDDO 
RETURN aArray