Function SetLocale() Foundation

// The example lists all country-specific settings 
// to a file and displays it using MemoEdit() 

#include "Nls.ch" 

PROCEDURE Main 
   LOCAL aSettings := { ; 
   { "NLS_ICOUNTRY    " , NLS_ICOUNTRY     }, ; 
   { "NLS_SLIST       " , NLS_SLIST        }, ; 
   { "NLS_SDECIMAL    " , NLS_SDECIMAL     }, ; 
   { "NLS_STHOUSAND   " , NLS_STHOUSAND    }, ; 
   { "NLS_SCURRENCY   " , NLS_SCURRENCY    }, ; 
   { "NLS_ICURRENCY   " , NLS_ICURRENCY    }, ; 
   { "NLS_ICURRDIGITS " , NLS_ICURRDIGITS  }, ; 
   { "NLS_SDATE       " , NLS_SDATE        }, ; 
   { "NLS_IDATE       " , NLS_IDATE        }, ; 
   { "NLS_ICENTURY    " , NLS_ICENTURY     }, ; 
   { "NLS_STIME       " , NLS_STIME        }, ; 
   { "NLS_ITIME       " , NLS_ITIME        }, ; 
   { "NLS_S1159       " , NLS_S1159        }, ; 
   { "NLS_S2359       " , NLS_S2359        }, ; 
   { "NLS_STIMEZONE   " , NLS_STIMEZONE    }, ; 
   { "NLS_ITZBIAS     " , NLS_ITZBIAS      }, ; 
   { "NLS_SYES        " , NLS_SYES         }, ; 
   { "NLS_SNO         " , NLS_SNO          }, ; 
   { "NLS_SDAYNAME1   " , NLS_SDAYNAME1    }, ; 
   { "NLS_SDAYNAME2   " , NLS_SDAYNAME2    }, ; 
   { "NLS_SDAYNAME3   " , NLS_SDAYNAME3    }, ; 
   { "NLS_SDAYNAME4   " , NLS_SDAYNAME4    }, ; 
   { "NLS_SDAYNAME5   " , NLS_SDAYNAME5    }, ; 
   { "NLS_SDAYNAME6   " , NLS_SDAYNAME6    }, ; 
   { "NLS_SDAYNAME7   " , NLS_SDAYNAME7    }, ; 
   { "NLS_SMONTHNAME1 " , NLS_SMONTHNAME1  }, ; 
   { "NLS_SMONTHNAME2 " , NLS_SMONTHNAME2  }, ; 
   { "NLS_SMONTHNAME3 " , NLS_SMONTHNAME3  }, ; 
   { "NLS_SMONTHNAME4 " , NLS_SMONTHNAME4  }, ; 
   { "NLS_SMONTHNAME5 " , NLS_SMONTHNAME5  }, ; 
   { "NLS_SMONTHNAME6 " , NLS_SMONTHNAME6  }, ; 
   { "NLS_SMONTHNAME7 " , NLS_SMONTHNAME7  }, ; 
   { "NLS_SMONTHNAME8 " , NLS_SMONTHNAME8  }, ; 
   { "NLS_SMONTHNAME9 " , NLS_SMONTHNAME9  }, ; 
   { "NLS_SMONTHNAME10" , NLS_SMONTHNAME10 }, ; 
   { "NLS_SMONTHNAME11" , NLS_SMONTHNAME11 }, ; 
   { "NLS_SMONTHNAME12" , NLS_SMONTHNAME12 }  } 

   SET ALTERNATE TO NLS.TXT 
   SET ALTERNATE ON 
   AEval( aSettings, ; 
          {|a| QOut( a[1], '"'+SetLocale( a[2] )+'"' ) } ) 

   SET ALTERNATE OFF 
   SET ALTERNATE TO 
   CLS 
   Memoedit( MemoRead( "NLS.TXT" ) ) 

RETURN 

// The example demonstrates how to define display 
// formats for numbers and logical values. 

#include "Nls.ch" 

PROCEDURE Main 
   LOCAL nNumber := 1234567.89 
   LOCAL cPicture:= "999,999,999.99" 
   LOCAL lTrue   := .T., lFalse := .F. 
   LOCAL dDate   := Date() 

   ? nNumber                            // result:    1234567,89 
   ? Str( nNumber )                     // result:    1234567.89 
   ? Transform( nNumber, cPicture )     // result:  1.234.567,89 

   SetLocale( NLS_STHOUSAND  , "t" ) 
   SetLocale( NLS_SDECIMAL   , "d" ) 

   ? nNumber                            // result:    1234567d89 
   ? Str( nNumber )                     // result:    1234567.89 
   ? Transform( nNumber, cPicture )     // result:  1t234t567d89 

   ? lTrue , Transform( lTrue , "Y" )   // result: .T. T 
   ? lFalse, Transform( lFalse, "Y" )   // result: .F. F 

   SetLocale( NLS_SYES , "1" ) 
   SetLocale( NLS_SNO  , "0" ) 

   ? lTrue , Transform( lTrue , "Y" )   // result: .T. 0 
   ? lFalse, Transform( lFalse, "Y" )   // result: .F. 1 

   // Only 0 and 1 is accepted as input for logical values 
   @ row()  , 0 SAY "True " GET lTrue  PICTURE "Y" 
   @ row()+1, 0 SAY "False" GET lFalse PICTURE "Y" 
   READ 

RETURN 

// The example shows different possibilities of 
// formatting numbers as currency. 

#include "Nls.ch" 

PROCEDURE Main 
   LOCAL nNumber := 12345.67 
   LOCAL cPicture:= "@$ 999,999.99" 

   ? nNumber                            // result:    12345,67 
   ? Transform( nNumber, cPicture )     // result: 12.345,67 DM 

   SetLocale( NLS_STHOUSAND, "'"  ) 
   SetLocale( NLS_SDECIMAL , "."  ) 
   SetLocale( NLS_SCURRENCY, "FF" ) 

   ? Transform( nNumber, cPicture )     // result: 12'345.67 FF 

   SetLocale( NLS_ICURRENCY, "0"  ) 
   ? Transform( nNumber, cPicture )     // result: FF12'345.67 

   SetLocale( NLS_ICURRENCY, "1"  ) 
   ? Transform( nNumber, cPicture )     // result: 12'345.67FF 

   SetLocale( NLS_ICURRENCY, "2"  ) 
   ? Transform( nNumber, cPicture )     // result: FF 12'345.67 

   SetLocale( NLS_ICURRENCY, "3"  ) 
   ? Transform( nNumber, cPicture )     // result: 12'345.67 FF 

RETURN 

// The program demonstrates the procedure how to 
// prepare an application for the European currency symbol 
// 
// TEST.PRG 
// 
// Compile & Link: xpp test /link:"/PM:PM" 
// 

#include "Appevent.ch" 
#include "Font.ch" 
#include "Nls.ch" 

PROCEDURE MAIN 
   LOCAL nEvent, mp1, mp2, oXbp 
   SETCOLOR( "N/W" ) 
   CLS 

   SetLocale( NLS_SCURRENCY, Chr(213) ) 
   ? "Euro OFF Chr(213) =", Chr(213) 
   WAIT 
   SetLocale( NLS_ICURRENCYEURO, "1" ) 

   // Configure the XbpCrt window, so the new font 
   // containing the Euro character becomes effective 
   SetAppWindow():configure() 
   SetColor( "N/W" ) 
   CLS 
   ? "Euro ON  Chr(213) =", Chr(213) 

   // Select characters as currency symbol 
   SetLocale( NLS_SCURRENCY, "$" ) 
   ? "Dollar in PICTURE", Transform( 123.45, "@$" ) 

   SetLocale( NLS_SCURRENCY, Chr(213) ) 
   ? "Euro   in PICTURE", Transform( 123.45, "@$" ) 

   // Entering the Euro sign in an SLE requires 
   // a font supporting this character 
   oXbp := XbpSLE():new(,,{50,200}, {300,24}) 
   oXbp:create() 
   oXbp:setFontCompoundName( FONT_HELV_MEDIUM ) 
   oXbp:setData( "Press AltGr+5" ) 

   DO WHILE nEvent <> xbeP_Close 
      nEvent := AppEvent( @mp1, @mp2, @oXbp ) 
      oXbp:handleEvent( nEvent, mp1, mp2 ) 
   ENDDO 
RETURN