Commands and Statements Commands and Statements

Command SET CONSOLE Foundation

Turns off or reactivates screen display.

Syntax
SET CONSOLE ON | off | <lToggle>
Scope
process-wide
Parameters
<lToggle>
<lToggle> is a logical expression which must appear in parentheses. Instead of the logical expression, the option ON can be specified for the value .T. (true) or OFF for the value .F. (false). When .T. or ON is specified (the default value), all output is displayed on the screen. If the setting is set to OFF, output on the screen using commands like ? or ?? is suppressed. Output with @...SAY remains, however, unaffected by SET CONSOLE OFF.
Description

The command SET CONSOLE suppresses or reactivates output of characters on the screen. This suppresses output from all output commands and functions that do not allow screen coordinates to be specified. This includes commands like ? or LIST and functions like QOut() or QQOut(), which always begin output at the current cursor position. The command @...SAY, however, remains unaffected by SET CONSOLE. To suppress @...SAY output, the current output device must be set to the printer using SET DEVICE TO PRINTER.

When SET CONSOLE is set to ON, output is displayed on the screen. There can also be parallel output to the printer (command SET PRINTER) or to a file (command SET ALTERNATE).

Examples
SET CONSOLE 
// In the example, addresses from an address file are listed. 
// Output occurs only at the printer and not on the screen. 

PROCEDURE Main 
   USE Address NEW 

   SET PRINTER ON 
   SET CONSOLE OFF 

   DO WHILE .NOT. Eof() 
      ? LName, FName 
      ? Street 
      ? City + ",", State, Zip 
      ? 
      SKIP 
   ENDDO 

   SET PRINTER OFF 
   SET PRINTER TO                    // close print device 
   SET CONSOLE ON 
   USE 
RETURN
Feedback

If you see anything in the documentation that is not correct, does not match your experience with the particular feature or requires further clarification, please use this form to report a documentation issue.